What is this strange "fog"border?

[Flockeeey 1]

hi guys,

 

i recently changend some weathersettings im my exileserverconfig and now i have like a paranormal circle fog border

dont know how to describe it, i attatched a pic

does anybody know how to change it?

yes i could set the weathersettings back but im interested in what this is :-)

thx in advance :-)

[Tobias Solem 559]

My guess is that it's a clientside glitch.

Try restarting your computer.

[Z80CPU 527]

Hello Flockeeey,

 

Could be a few things:

1 - The view distance limit is a 'fog wall' to put it simply

2 - Glitch as Tobias has said

3 - Messed up video driver, driver settings (windows), or ARMA video settings

4 - A 'weird' mod

5 - Outdated/unsupported video driver

 

Me?  I would reboot and then check #3 and #5 if problem still exist.

 

Good luck to ya!

 

 

[yukihito23 91]

I've seen this happen on my server in certain conditions. usually happens rarely during morning hours when fog is a certain value or something + certain weather type.

It's certainly not client side only as several have reported it at the same time and ,i've observed it as well but since it only happens rarly for us, I'm ignoring it.

[Chernaruski 54]

I think I fixed it.
I was using old version of random weather script (1.3). If you used it and had similar problem, get a 1.4 from armaholic. Then change real_weather.sqf to:

 

Spoiler

 

	/*
	Author: code34 [email protected]
	Copyright (C) 2013-2015 Nicolas BOITEUX

	Real weather for MP GAMES v 1.4
	
	This program is free software: you can redistribute it and/or modify
	it under the terms of the GNU General Public License as published by
	the Free Software Foundation, either version 3 of the License, or
	(at your option) any later version.
	
	This program is distributed in the hope that it will be useful,
	but WITHOUT ANY WARRANTY; without even the implied warranty of
	MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
	GNU General Public License for more details.
	
	You should have received a copy of the GNU General Public License
	along with this program.  If not, see <http://www.gnu.org/licenses/>. 
	*/

	private ["_lastrain", "_rain", "_fog", "_mintime", "_maxtime", "_overcast", "_realtime", "_random","_startingdate", "_startingweather", "_timeforecast", "_daytimeratio", "_nighttimeratio", "_timesync", "_wind"];
	
	// Real time vs fast time
	// true: Real time is more realistic weather conditions change slowly (ideal for persistent game)
	// false: fast time give more different weather conditions (ideal for non persistent game) 
	_realtime = false;

	// Random time before new forecast
	// true: forecast happens bewteen mintime and maxtime
	// false: forecast happens at mintime
	_random = false;

	// Min time seconds (real time) before a new weather forecast
	_mintime = 600;

	// Max time seconds (real time) before a new weather forecast
	_maxtime = 1200;

	// If Fastime is on
	// Ratio 1 real time second for x game time seconds
	// Default: 1 real second = 6 second in game
	_daytimeratio = 5;
	_nighttimeratio = 24;

	// send sync data across the network each xxx seconds
	// 60 real seconds by default is a good value
	// shortest time do not improve weather sync
	_timesync = 60;

	// Mission starting date is 25/09/2013 at 12:00
	_startingdate = [2015, 07, 01, 07, 00];

	// Mission starting weather "CLEAR|CLOUDY|RAIN";
	_startingweather = ["CLEAR", "CLOUDY", "RAIN","CLEAR","CLEAR","CLEAR"] call BIS_fnc_selectRandom;

	/////////////////////////////////////////////////////////////////
	// Do not edit below
	/////////////////////////////////////////////////////////////////
	
	if(_mintime > _maxtime) exitwith {hint format["Real weather: Max time: %1 can no be higher than Min time: %2", _maxtime, _mintime];};
	_timeforecast = _mintime;

	setdate _startingdate;
	switch(toUpper(_startingweather)) do {
		case "CLEAR": {
			wcweather = [0, 0, 0, [random 3, random 3, true], date];
		};
		
		case "CLOUDY": {
			wcweather = [0, 0, 0.6, [random 3, random 3, true], date];
		};
		
		case "RAIN": {
			wcweather = [1, 0, 1, [random 3, random 3, true], date];
		};

		default {
			// clear
			wcweather = [0, 0, 0, [random 3, random 3, true], date];
			diag_log "Real weather: wrong starting weather";
		};
	};

	// add handler
	if (local player) then {
		wcweatherstart = true;
		"wcweather" addPublicVariableEventHandler {
			// first JIP synchronization
			if(wcweatherstart) then {
				wcweatherstart = false;
				skipTime -24;
				86400 setRain (wcweather select 0);
				86400 setfog (wcweather select 1);
				86400 setOvercast (wcweather select 2);
				skipTime 24;
				simulweatherSync;
				setwind (wcweather select 3);
				setdate (wcweather select 4);
			}else{
				wcweather = _this select 1;
				60 setRain (wcweather select 0);
				60 setfog (wcweather select 1);
				60 setOvercast (wcweather select 2);
				setwind (wcweather select 3);
				setdate (wcweather select 4);
			};
		};
	};

	// SERVER SIDE SCRIPT
	if (!isServer) exitWith{};

	// apply weather
	skipTime -24;
	86400 setRain (wcweather select 0);
	86400 setfog (wcweather select 1);
	86400 setOvercast (wcweather select 2);
	skipTime 24;
	simulweatherSync;
	setwind (wcweather select 3);
	setdate (wcweather select 4);

	// sync server & client weather & time
	[_realtime, _timesync, _daytimeratio, _nighttimeratio] spawn {
		private["_realtime", "_timesync", "_daytimeratio", "_nighttimeratio"];
		
		_realtime = _this select 0;
		_timesync = _this select 1;
		_daytimeratio = _this select 2;
		_nighttimeratio =  _this select 3;

		while { true } do {
			wcweather set [4, date];
			publicvariable "wcweather";
			if(!_realtime) then { 
				if((date select 3 > 16) or (date select 3 <6)) then {
					setTimeMultiplier _nighttimeratio;
				} else {
					setTimeMultiplier _daytimeratio;
				};
			};
			sleep _timesync;
		};
	};

	_lastrain = 0;
	_rain = 0;
	_overcast = 0;

	while {true} do {
		_overcast = random 1;
		if(_overcast > 0.70) then {
			_rain = random 1;
		} else {
			_rain = 0;
		};
		if((date select 3 > 2) and (date select 3 <6)) then {
			if(random 1 > 0.75) then {
				_fog = 0.3 + (random 0.1);
			} else {
				_fog = 0.1 + (random 0.1);
			};
		} else {
			if((_lastrain > 0.6) and (_rain < 0.2)) then {
				_fog = random 0.2;
			} else {
				_fog = 0;
			};
		};
		if(random 1 > 0.95) then {
			_wind = [random 7, random 7, true];
		} else {
			_wind = [random 3, random 3, true];
		};
		_lastrain = _rain;

		wcweather = [_rain, _fog, _overcast, _wind, date];
		60 setRain (wcweather select 0);
		60 setfog (wcweather select 1);
		60 setOvercast (wcweather select 2);
		setwind (wcweather select 3);
		if(_random) then {
			_timeforecast = _mintime + (random (_maxtime - _mintime));
		};
		sleep _timeforecast;
	};

 

 

 

 

 

 

 

Edited October 19, 2017 by Chernaruski
fixed

[Z80CPU 527]

I saw this the other day.  It appears to happen when you have fog and the time acceleration is set to 'some high number', this happens.  Even with using InfiSTAR and 'flying up', this 'circle' never left me.

It seems to only happen when the fog lifts quickly.

I am using the default Exile weather with 24 hours in a 4 hour period.

 

[Sgt Smash 153]

On 10/20/2017 at 12:44 AM, Z80CPU said:

I saw this the other day.  It appears to happen when you have fog and the time acceleration is set to 'some high number', this happens.  Even with using InfiSTAR and 'flying up', this 'circle' never left me.

It seems to only happen when the fog lifts quickly.

I am using the default Exile weather with 24 hours in a 4 hour period.

 

Same here, did you find away of fixing it without having to change the time acceleration?

[Z80CPU 527]

Not really outside of reducing the fog levels themselves.

It sucks too...just add it to the list of 'lovely items' that are collectively known as ARMA...

 

[CartoonBOY 0]

This happens because one or more of your weather keyframes is set to 0 fog. You will need at least 0.1 on all keyframes.