[SOLVED] Poptabs showing as ANY

[King Raymond 4]

Hi There, 

I have a weird issue where in my XM8, my poptabs display as ANY.

Doesnt matter if I remove all tabs or add tons of tabs. It reflects on my statusbar, but not in the XM8. Anyone know the location of where I can check for this? 

Thanks

[WolfkillArcadia 758]

You probably are running an out-of-date script that overwrites ExileClient_gui_xm8_slide_apps_onOpen. The money variable changed from `ExileClientPlayerMoney` to `player getVariable ["ExileMoney",0]`

[King Raymond 4]

Well, that would explain it. Do you know where the new script is located or do I need to edit it myself? 

[itsJylerTAG 2]

33 minutes ago, King Raymond said:

Well, that would explain it. Do you know where the new script is located or do I need to edit it myself? 

Well, if you know how to edit the status bar and upload to your server, then just open the statusBar.sqf file in something like notepad or notepad++ and change following line from 

 

This; _wallet = ExileClientPlayerMoney;

to

This; _wallet = player getVariable ["ExileMoney",0];

 

I did it 5 minutes ago for my server and it worked perfectly.

 

 

 

Edited July 8, 2016 by itsJylerTAG

[King Raymond 4]

@itsJylerTAG

I am not trying to update my statusbar, i am trying to update my XM8.

I have managed to get it to display 0 poptabs. But now matter how much I give myself or take away, it still displays 0

[itsJylerTAG 2]

6 minutes ago, King Raymond said:

@itsJylerTAG

I am not trying to update my statusbar, i am trying to update my XM8.

I have managed to get it to display 0 poptabs. But now matter how much I give myself or take away, it still displays 0

I see, well i apologize for the misunderstanding. If i come across a fix i'll be sure you let you know!

[King Raymond 4]

Thank, appreciate it.

[oSoDirty 167]

@King Raymond

If you're using xm8apps by Shix, this is the new ExileClient_gui_xm8_slide_apps_onOpen.sqf

Spoiler

/**
 * ExileClient_gui_xm8_slide_apps_onOpen
 *
 * Exile Mod
 * exile.majormittens.co.uk
 * © 2015 Exile Mod Team
 *
 * This work is licensed under the Creative Commons Attribution-NonCommercial-NoDerivatives 4.0 International License. 
 * To view a copy of this license, visit http://creativecommons.org/licenses/by-nc-nd/4.0/.
 */
 
private["_display","_killDeathRatio","_killDeathRatioControl","_popTabsValue","_popTabs","_respectValue","_respect"];
disableSerialization;
_display = uiNameSpace getVariable ["RscExileXM8", displayNull];
if (ExileClientPlayerDeaths < 1) then 
{
	_killDeathRatio = ExileClientPlayerKills;
}
else 
{
	_killDeathRatio = [ExileClientPlayerKills / ExileClientPlayerDeaths, 2] call ExileClient_util_math_round;
};
_killDeathRatioControl = _display displayCtrl 4057;
_killDeathRatioControl ctrlSetTooltip format ["%1 Kills / %2 Deaths", ExileClientPlayerKills, ExileClientPlayerDeaths];
_killDeathRatioControl ctrlSetStructuredText parseText (format ["<t color='#00b2cd' font='OrbitronLight' size='1.6' valign='middle' align='center' shadow='0'><br/><br/><br/><t font='OrbitronMedium' size='3.5' color='#ffffff'>%1</t><br/>K/D</t>", _killDeathRatio]);
_popTabsValue = (player getVariable ["ExileLocker", 0]);
if (_popTabsValue > 999) then
{
	_popTabsValue = format ["%1k", floor (_popTabsValue / 1000)];
};
_popTabs = _display displayCtrl 4058;
_popTabs ctrlSetTooltip format["You have %1 Pop Tabs in your locker", (player getVariable ["ExileLocker", 0])];
_popTabs ctrlSetStructuredText parseText (format ["<t color='#00b2cd' font='OrbitronLight' size='1.6' valign='middle' align='center' shadow='0'><br/><br/><br/><t font='OrbitronMedium' size='3.5' color='#ffffff'>%1</t><br/>POP TABS</t>", _popTabsValue]);
_respectValue = ExileClientPlayerScore;
if (_respectValue > 999) then
{
	_respectValue = format ["%1k", floor (_respectValue / 1000)];
};
_respect = _display displayCtrl 4059;
_respect ctrlSetTooltip format["%1", ExileClientPlayerScore];
_respect ctrlSetStructuredText parseText (format ["<t color='#00b2cd' font='OrbitronLight' size='1.6' valign='middle' align='center' shadow='0'><br/><br/><br/><t font='OrbitronMedium' size='3.5' color='#ffffff'>%1</t><br/>RESPECT</t>", _respectValue]);


/*
You can now set what buuton you would like to replace
1 = server info button
2 = Bounties Button
3 = Clan Button
*/
_btnToUse = 1;

_AppsLogo = "xm8Apps\images\xm8logofix_ca.paa";

if(_btnToUse == 1)then{
// clear server info button text
//Will set the text on the server info button to "XM8 Apps"
_serverInfo = _display displayCtrl 1107;
_serverInfo ctrlSetText "";
_serverInfo ctrlSetFade 1;
_serverInfo ctrlCommit 0;

_newIcon = _display ctrlCreate ["RscPicture", 9897, _display displayCtrl 4040];
_newIcon ctrlSetPosition [(24.25 - 3) * (0.025), (15.5 - 2) * (0.04), 2.75 * (0.04), 2.75 * (0.04)];
_newIcon ctrlCommit 0.01;
_newIcon ctrlSetText _AppsLogo;

_newControl = _display ctrlCreate ["RscExileXM8AppButton1x1", 9898, _display displayCtrl 4040];
_newControl ctrlSetPosition [(23.5 - 3) * (0.025), (15 - 2) * (0.04)];
_newControl ctrlCommit 0.01;
_newControl ctrlSetEventHandler ["ButtonClick", "execVM'xm8Apps\XM8Apps_Init.sqf';"];
_newControl ctrlSetStructuredText (parseText (format ["XM8 Apps"]));
};

if(_btnToUse == 2)then{
// clear server info button text
//Will set the text on the server info button to "XM8 Apps"
_serverInfo = _display displayCtrl 1103;
_serverInfo ctrlSetText "";
_serverInfo ctrlSetFade 1;
_serverInfo ctrlCommit 0;

_newIcon = _display ctrlCreate ["RscPicture", 9897, _display displayCtrl 4040];
_newIcon ctrlSetPosition [(17.9 - 3) * (0.025), (15.5 - 2) * (0.04), 2.75 * (0.04), 2.75 * (0.04)];
_newIcon ctrlCommit 0.01;
_newIcon ctrlSetText _AppsLogo;

_newControl = _display ctrlCreate ["RscExileXM8AppButton1x1", 9898, _display displayCtrl 4040];
_newControl ctrlSetPosition [(17 - 3) * (0.025), (15 - 2) * (0.04)];
_newControl ctrlCommit 0.01;
_newControl ctrlSetEventHandler ["ButtonClick", "execVM'xm8Apps\XM8Apps_Init.sqf';"];
_newControl ctrlSetStructuredText (parseText (format ["XM8 Apps"]));
};

if(_btnToUse == 3)then{
// clear server info button text
//Will set the text on the server info button to "XM8 Apps"
_serverInfo = _display displayCtrl 1105;
_serverInfo ctrlSetText "";
_serverInfo ctrlSetFade 1;
_serverInfo ctrlCommit 0;

_newIcon = _display ctrlCreate ["RscPicture", 9897, _display displayCtrl 4040];
_newIcon ctrlSetPosition [(30.8 - 3) * (0.025), (4.5 - 2) * (0.04), 2.75 * (0.04), 2.75 * (0.04)];
_newIcon ctrlCommit 0.01;
_newIcon ctrlSetText _AppsLogo;

_newControl = _display ctrlCreate ["RscExileXM8AppButton1x1", 9898, _display displayCtrl 4040];
_newControl ctrlSetPosition [(30 - 3) * (0.025), (4 - 2) * (0.04)];
_newControl ctrlCommit 0.01;
_newControl ctrlSetEventHandler ["ButtonClick", "execVM'xm8Apps\XM8Apps_Init.sqf';"];
_newControl ctrlSetStructuredText (parseText (format ["XM8 Apps"]));
};

 

 

Edited July 8, 2016 by oSoDirty

[King Raymond 4]

@oSoDirty, 

Is there a link of some sort to update so I can update the entire system? It appears that fixing just that file, still causes the poptabs to display as "0"

[oSoDirty 167]

No, I made the edit myself. Works fine for my servers.