Rocket Launchers

[JackHart 10]

I searched around and didnt see anyone post about this and im not 100% sure this is the place. But my issue with the launchers is that they wont place them on the person when you purchase them. Ive added them in, they show up no issues there. ive tried adding them to multiple traders to see if it makes a difference, but im not having any luck. Am i missing a step somewhere? If anyone can help out thanks in advance.

[justinlee 16]

you can add them in but unless u find a way get them spawn at player feet then it will only take the popcaps and give you nothing

[humpabry 5]

get players to select vehicle on top left box at trader...then buy them..they spawn inside vehicles

thats the only way atm 

[dvinskiy 0]

/**
 * Exile Mod
 * exile.majormittens.co.uk
 * © 2015 Exile Mod Team
 *
 * This work is licensed under the Creative Commons Attribution-NonCommercial-NoDerivatives 4.0 International License. 
 * To view a copy of this license, visit http://creativecommons.org/licenses/by-nc-nd/4.0/.
 */
 
private["_player","_itemClassName","_itemInformation","_itemCategory","_itemType","_added","_compatibleWeaponItems"];
_player = _this select 0;
_itemClassName = toLower (_this select 1); 
_itemInformation = [_itemClassName] call BIS_fnc_itemType;
_itemCategory = _itemInformation select 0;
_itemType = _itemInformation select 1;
_added = false;
if (_itemCategory isEqualTo "Magazine") then
{
    {
        if !(_x isEqualTo "") then
        {
            switch (_forEachIndex) do
            {
                case 0: 
                { 
                    if ((primaryWeaponMagazine _player) isEqualTo []) then 
                    { 
                        _compatibleWeaponItems = _x call ExileClient_util_gear_getCompatibleWeaponItems;
                        if (_itemClassName in _compatibleWeaponItems) exitWith
                        {    
                            _player addPrimaryWeaponItem _itemClassName; 
                            _added = true;
                        };
                    }; 
                };
                case 1: 
                { 
                    if ((secondaryWeaponMagazine _player) isEqualTo []) then 
                    { 
                        _compatibleWeaponItems = _x call ExileClient_util_gear_getCompatibleWeaponItems;
                        if (_itemClassName in _compatibleWeaponItems) exitWith
                        {    
                            _player addSecondaryWeaponItem _itemClassName; 
                            _added = true;
                        };
                    }; 
                };
                case 2: 
                { 
                    if ((handgunMagazine _player) isEqualTo []) then 
                    { 
                        _compatibleWeaponItems = _x call ExileClient_util_gear_getCompatibleWeaponItems;
                        if (_itemClassName in _compatibleWeaponItems) exitWith
                        {    
                            _player addHandgunItem _itemClassName; 
                            _added = true;
                        };
                    }; 
                };
            };
        };
    }
    forEach [primaryWeapon _player, secondaryWeapon _player, handgunWeapon _player];
}
else 
{
    switch (_itemType) do 
    {
        case "AssaultRifle", 
        case "Rifle", 
        case "SniperRifle", 
        case "SubmachineGun", 
        case "MachineGun", 
        case "Handgun", 
        case "LaserDesignator", 
        case "Throw",
        case "Binocular", 
        case "RocketLauncher",
        case "MissileLauncher":
        {
            _player addWeaponGlobal _itemClassName;     
            _added = true;
        };
        case "GPS", 
        case "Map", 
        case "Radio", 
        case "UAVTerminal", 
        case "Watch", 
        case "Compass", 
        case "NVGoggles", 
        case "Glasses": 
        {
            _player linkItem _itemClassName;
            _added = true;
        };
        case "Headgear":     { _player addHeadgear _itemClassName; _added = true; }; 
        case "Backpack":     { _player addBackpackGlobal _itemClassName; _added = true; }; 
        case "Uniform":     { _player forceAddUniform _itemClassName; _added = true; }; 
        case "Vest":         { _player addVest _itemClassName; _added = true; }; 
        case "AccessorySights", 
        case "AccessoryPointer", 
        case "AccessoryMuzzle", 
        case "AccessoryBipod": 
        {
            {
                if !(_x isEqualTo "") then
                {
                    _compatibleWeaponItems = _x call ExileClient_util_gear_getCompatibleWeaponItems;
                    if (_itemClassName in _compatibleWeaponItems) exitWith
                    {    
                        switch (_forEachIndex) do
                        {
                            case 0: { _player addPrimaryWeaponItem _itemClassName; _added = true; }; 
                            case 1: { _player addSecondaryWeaponItem _itemClassName; _added = true; }; 
                            case 2: { _player addHandgunItem _itemClassName; _added = true; }; 
                        };
                    };
                };
            }
            forEach [primaryWeapon _player, secondaryWeapon _player, handgunWeapon _player];
        };
    };
};
_added

[POLM_GekkeGerrit 5]

And what file do we edit for that?
Thanks

Edited October 20, 2015 by POLM_GekkeGerrit

[READTHESCROLL 203]

And what file do we edit for that?
Thanks

ExileClient_util_playerEquipment_add.sqf

[[OMG]Slim 62]

We eventually found it, but thank you pal

[READTHESCROLL 203]

Anyone else have an issue where if you buy rockets it auto loads the first one if the launcher is empty and starts making this sound like a glitched sound file?

[[OMG]Slim 62]

Anyone else have an issue where if you buy rockets it auto loads the first one if the launcher is empty and starts making this sound like a glitched sound file?

Does it happen with every launcher?

[PristineBroAudi 0]

ExileClient_util_playerEquipment_add.sqf

i dont have that folder in \@ExileServer\addons/exile_server folder were is that folder is i still have trouble whit rocket luncher in exille