Malden Barracks: no loot [SOLVED]

[aussie battler 282]

Hey
Just wondering if anyone has got loot to spawn in the barracks on Malden?

I tried to do the standard loot positions & my own loot positions but no loot spawns in the barracks...

The only thing I can think of is maybe because the building is a camo variant its class name is slightly different? I brought it up in the editor and it says camo the same class name.

 

Spoiler

class Land_i_Barracks_V1_F

{

table = "Military";

positions[] = {{-0.464844, 3.49219, 0.605521}, {-0.476563, 3.95703, 3.9395}, {-10.4844, -3.32422, 3.9395}, {-11.1055, -2.92188, 0.605521}, {-12.3066, 0.222656, 0.605521}, {-2.29688, -4.23828, 0.605283}, {-3.89648, -4.80078, 3.93923}, {-8.66992, 3.86328, 0.605521}, {-9.03516, 3.31055, 3.9395}, {10.3301, 2.77734, 0.605521}, {10.4023, 3.18945, 3.9395}, {13.0352, -3.23438, 3.9395}, {13.1738, -3.31055, 0.605521}, {3.57227, -3.49414, 0.605522}, {3.61133, -2.98047, 3.9395}, {6.38281, 3.41992, 0.60552}, {6.4082, 2.87695, 3.9395}};

};

 

Edited June 29, 2017 by aussie battler

[[HG]RaVeN103 207]

I don't use Malden, but the problem was already on other maps.

ExileClient_system_lootManager_thread_spawn.sqf

change line 19

_buildings = player nearObjects ["House", _spawnRadius];

to

_buildings = nearestObjects [player, ["Building","House"], _spawnRadius];

Spoiler

/**
 * ExileClient_system_lootManager_thread_spawn
 *
 * Exile Mod
 * exile.majormittens.co.uk
 * © 2015 Exile Mod Team
 *
 * This work is licensed under the Creative Commons Attribution-NonCommercial-NoDerivatives 4.0 International License. 
 * To view a copy of this license, visit http://creativecommons.org/licenses/by-nc-nd/4.0/.
 */
 
private["_spawnRadius","_minimumDistanceToTraderZones","_minimumDistanceToTerritories","_lootLifeTime","_buildings","_buildingNetIdsToSpawnLootIn","_building","_lastTimeSentToServer"];
if !(alive player) exitWith {false};
if !((vehicle player) isEqualTo player) exitWith {false};
_spawnRadius = getNumber (missionConfigFile >> "CfgExileLootSettings" >> "spawnRadius");
_minimumDistanceToTraderZones = getNumber (missionConfigFile >> "CfgExileLootSettings" >> "minimumDistanceToTraderZones");
_minimumDistanceToTerritories = getNumber (missionConfigFile >> "CfgExileLootSettings" >> "minimumDistanceToTerritories");
_lootLifeTime = getNumber (missionConfigFile >> "CfgExileLootSettings" >> "lifeTime") * 60;
_buildings = nearestObjects [player, ["Building","House"], _spawnRadius];
_buildingNetIdsToSpawnLootIn = [];
{
    _building = _x;
    try 
    {
        if (isObjectHidden _building) throw false;
        _lastTimeSentToServer = _building getVariable ["ExileLastLootRequestedAt", -99999];
        if ((time - _lastTimeSentToServer) < _lootLifeTime) throw false;
        if (_minimumDistanceToTraderZones > 0) then
        {
            if ([_building, _minimumDistanceToTraderZones] call ExileClient_util_world_isTraderZoneInRange) then
            {
                throw false;
            };
        };
        if (_minimumDistanceToTerritories > 0) then
        {
            if ([_building, _minimumDistanceToTerritories] call ExileClient_util_world_isTerritoryInRange) then
            {
                throw false;
            };
        };
        _buildingNetIdsToSpawnLootIn pushBack (netId _building);
        _building setVariable ["ExileLastLootRequestedAt", time];
    }
    catch 
    {
    };
}
forEach _buildings;
if ((count _buildingNetIdsToSpawnLootIn) > 0) then 
{
    ["spawnLootRequest", [_buildingNetIdsToSpawnLootIn]] call ExileClient_system_network_send;
};

should work

[CplFull 3]

This change has to be done by every user? since you are changing it on the client on server ?

[[HG]RaVeN103 207]

This file works on Clientside, so

put this in your MPMission as ExileCustomCode.

[CplFull 3]

Thank you

That explains it..

Thanks

{TNT}CplFull

 

 

 

[aussie battler 282]

@[HG]RaVeN103 LEGEND!!

Nice work, thanks for the help. That would also explain why my wrecks didn't have loot.

I am going to try throwing some wreck class names in the line & see how that goes down.

No loot in those barracks was beginning to feel like I was playing Dayz Standalone.

[gfourth 39]

On 6/28/2017 at 11:00 AM, [HG]RaVeN103 said:

This file works on Clientside, so

put this in your MPMission as ExileCustomCode.

I may be able to figure this out as I have done a few overrides to exilecustomcode via instructions given, but any chance you can outline the process of doing this? If not no worries, I will do my due diligence to get it figured out!

[aussie battler 282]

Its in your config.cpp file under custom code. @gfourth

[aussie battler 282]

class CfgExileCustomCode
{
ExileClient_system_lootManager_thread_spawn = "fixes\ExileClient_system_lootManager_thread_spawn.sqf "
};

 

No put ExileClient_system_lootManager_thread_spawn in a new folder called fixes in your mpmission file and repack it.

[gfourth 39]

13 minutes ago, aussie battler said:

class CfgExileCustomCode
{
ExileClient_system_lootManager_thread_spawn = "fixes\ExileClient_system_lootManager_thread_spawn.sqf "
};

 

No put ExileClient_system_lootManager_thread_spawn in a new folder called fixes in your mpmission file and repack it.

Ahh thank you kindly Sir!  I was on the right track in my head, but not quite, this helps tremendously.